marinos35's Wiimote Scripts

Site Admin Joined: 24 Jun 2006 Posts: 30

Here you can find scripts that I have created and also report any problems about them. Just copy the code to your GlovePIE window and save it with the name that you can see on the second line of the code.

NOTE: Next to the scripts' names you can see up to 4 capital letters (WSNC)
Those letters describe the accessories you can use with that script

W means that it works with a stand-alone Wiimote
S means that it works with Wiimote+Sensor Bar
N means that it works with Wiimote+Nunchuk
C means that it works with Wiimote+Classic Controller

So, if you see MouseS, that means that you can't use a stand-alone Wiimote without a Sensor Bar, while MouseWS would mean that you can use a Sensor Bar if you want to.

SCRIPTS SO FAR
UPDATED Zoom Player WNC about the program
UPDATED CDisplay WN about the program

COMING SOON
Mouse SNC - BETA AVALIABLE
WoW SN + WoW N - (The work here is slow for now, but the beta version may go public if there are people wanting to try it)

Beta scripts can be found posted as threads on the GlovePIE Wiimote Scripts section of this forum. You can also recommend programs to make scripts for. Please leave some feedback about the scripts, so I can make them better.

Site Admin Joined: 24 Jun 2006 Posts: 30

Zoom Player WNC Script by marinos35
Version 1.1

Changelog
- The script now hides the glovepie's window. Double click any Home button for the window to appear again (Wiimote or keyboard)
- Change to the rumble code. Now Wiimote rumbles once when you unlock it, and twice when you lock it. You can change the var.IwantRUMBLE to false to deactivate rumble.
- When Wiimote's battery runs low (somewhere at 6%) you will hear it once from your speakers. Also the battery info now appears in percents.
- LED's info changed, to be more accurate.
- minor code changes

COMPATIBLE with
Wiimote
Nunchuk
Classic Controller

INCOMPATIBLE with
Sensor Bar

HOW TO USE IT

ATTENTION: The GlovePIE window will hide itself once you run this script.
You can hide/unhide GlovePIE's window by double-clicking the Home button on your Wiimote, Classic Controller or keyboard.

This script offers Lock Key function. You have to press Home button once to unlock the keys. You can press it again to lock them once more.

You can use it with only a Wiimote for basic video shortcuts, or with a Nunchuk if you want to control the mouse also.
You can also use the Classic Controller. When connected, it deactivates the Wiimote's buttons and offers a combined Wiimote+Nunchuk functionality.

Video Shortcuts
(they only work when Zoom Player is the active program)

Play/Pause = A (Wiimote) or a (Classic)
show/hide Info Bar = B (Wiimote) or b (Classic)
Full Screen on/off = A+B (Wiimote) or x (Classic)
Fast Forward = 1 (Wiimote) or R (Classic)
Rewind = 2 (Wiimote) or ZR (Classic)
Next Chapter/File = D-Pad Right (Wiimote) or D-Pad Right (Classic)
Previous Chapter/File = D-Pad Left (Wiimote) or D-Pad Left (Classic)
Change Audio = D-Pad Up (Wiimote) or D-Pad Up (Classic)
Change Subtitles = D-Pad Down (Wiimote) or D-Pad Down (Classic)
Increase Volume = + (Wiimote) or + (Classic)
Decrease Volume = - (Wiimote) or - (Classic)
Mute on/off = - and + (Wiimote) or y (Classic)

Mouse Control

Move mouse = Analog (Nunchuk) or Left Analog (Classic)
Left Click = c (Nunchuk) or L (Classic)
Right Click = Z (Nunchuk) or ZL (Classic)

WHAT THE LEDS MEAN

No LEDS = Buttons locked or Wiimote not connected or script not active
Flashing LEDS = You just connected with your PC your Wiimote. Just press Home to unlock the buttons or script not active
2+3 LEDS = Wiimote buttons (and Nunchuk if connected) are working
1+4 LEDS = Only Classic Controller works

Save As zoomplayerWNC.PIE

Code:

// Zoom Player Script by marinos35
// filename: zoomplayerWNC.PIE
// Version 1.1
// http://WiiMoveU.GooglePages.com

/*
COMPATIBLE with
Wiimote
Nunchuk
Classic Controller

INCOMPATIBLE with
Sensor Bar

HOW TO USE IT

ATTENTION: The GlovePIE window will hide itself once you run this script.
You can hide/unhide GlovePIE's window by double-clicking the Home button on your Wiimote, Classic Controller or keyboard.

This script offers Lock Key function. You have to press Home button once to unlock the keys. You can press it again to lock them once more.

You can use it with only a Wiimote for basic video shortcuts, or with a Nunchuk if you want to control the mouse also.
You can also use the Classic Controller. When connected, it deactivates the Wiimote's buttons and offers a combined Wiimote+Nunchuk functionality.

Video Shortcuts
(they only work when Zoom Player is the active program)

Play/Pause = A (Wiimote) or a (Classic)
show/hide Info Bar = B (Wiimote) or b (Classic)
Full Screen on/off = A+B (Wiimote) or x (Classic)
Fast Forward = 1 (Wiimote) or R (Classic)
Rewind = 2 (Wiimote) or ZR (Classic)
Next Chapter/File = D-Pad Right (Wiimote) or D-Pad Right (Classic)
Previous Chapter/File = D-Pad Left (Wiimote) or D-Pad Left (Classic)
Change Audio = D-Pad Up (Wiimote) or D-Pad Up (Classic)
Change Subtitles = D-Pad Down (Wiimote) or D-Pad Down (Classic)
Increase Volume = + (Wiimote) or + (Classic)
Decrease Volume = - (Wiimote) or - (Classic)
Mute on/off = - and + (Wiimote) or y (Classic)

Mouse Control

Move mouse = Analog (Nunchuk) or Left Analog (Classic)
Left Click = c (Nunchuk) or L (Classic)
Right Click = Z (Nunchuk) or ZL (Classic)

WHAT THE LEDS MEAN

No LEDS = Buttons locked or Wiimote not connected or script not active
Flashing LEDS = You just connected with your PC your Wiimote. Just press Home to unlock the buttons or script not active
2+3 LEDS = Wiimote buttons (and Nunchuk if connected) are working
1+4 LEDS = Only Classic Controller works
*/

// Hide/Show GlovePIE window by double-clicking the Home button
if var.run == FALSE then
var.run = TRUE
HidePie
var.hidden = TRUE
endif

if ((DoubleClicked(Wiimote.Home) and Wiimote.HasClassic == FALSE) or (DoubleClicked(Home) and LeftShift == FALSE) or DoubleClicked(Wiimote.Classic.Home)) and var.hidden then
ShowPie
var.hidden = FALSE
elseif ((DoubleClicked(Wiimote.Home) and Wiimote.HasClassic == FALSE) or (DoubleClicked(Home) and LeftShift == FALSE) or DoubleClicked(Wiimote.Classic.Home)) and var.hidden == FALSE then
HidePie
var.hidden = TRUE
endif

// Rumbles when you lock or unlock keys.
var.IwantRUMBLE = TRUE // If you don't want the Rumble, then change the TRUE to FALSE

// Home button enables and disables the buttons. Function similar to the Lock Key
var.home = (SingleClicked(Wiimote.Home) and Wiimote.HasClassic == FALSE) or SingleClicked(Wiimote.Classic.Home)
If var.home and var.on then
If var.IwantRUMBLE then
Wiimote.Rumble = TRUE
wait 100ms
Wiimote.Rumble = FALSE
wait 150ms
Wiimote.Rumble = TRUE
wait 100ms
Wiimote.Rumble = FALSE
endif
var.on = FALSE
elseif var.home and var.on = FALSE then
If var.IwantRUMBLE then
Wiimote.Rumble = TRUE
wait 150ms
Wiimote.Rumble = FALSE
endif
var.on = TRUE
endif

// LEDS
Wiimote.Led1 = var.on and Wiimote.HasClassic //No LEDS = Buttons locked or Wiimote not connected or script not active
Wiimote.Led2 = var.on and Wiimote.HasClassic == FALSE //2+3 LEDS = Wiimote buttons (and Nunchuk if connected) are working
Wiimote.Led3 = var.on and Wiimote.HasClassic == FALSE //1+4 LEDS = Only Classic Controller works
Wiimote.Led4 = var.on and Wiimote.HasClassic //Flashing LEDS = You just connected with your PC your Wiimote. Just press Home to unlock the buttons

//Keys for Wiimote. Deactivated when a Classic Controller is connected
LeftControl+A = Wiimote.Up and var.on and Wiimote.HasClassic == FALSE // UP = change audio
LeftControl+B = Wiimote.Down and var.on and Wiimote.HasClassic == FALSE // DOWN = change subtitles
LeftShift+LeftBracket = Wiimote.Left and var.on and Wiimote.HasClassic == FALSE // LEFT = previous chapter
LeftShift+RightBracket = Wiimote.Right and var.on and Wiimote.HasClassic == FALSE // RIGHT = next chapter
p = Wiimote.A and var.on and Wiimote.HasClassic == FALSE // A = play/pause
Space = Wiimote.B and var.on and Wiimote.HasClassic == FALSE // B = info bar
LeftAlt+Enter = Wiimote.A and Wiimote.B and var.on and Wiimote.HasClassic == FALSE // A+B = full screen on/off
f = Wiimote.One and var.on and Wiimote.HasClassic == FALSE // 1 = fast forward
w = Wiimote.Two and var.on and Wiimote.HasClassic == FALSE // 2 = rewind
LeftControl+M = Wiimote.Minus and Wiimote.Plus and var.on and Wiimote.HasClassic == FALSE // - & + = mute
LeftShift+End = Wiimote.Minus and var.on and Wiimote.HasClassic == FALSE // - = decrease volume
LeftShift+Home = Wiimote.Plus and var.on and Wiimote.HasClassic == FALSE // + = increase volume

// Keys for Nunchuk
var.joyfix = 5 / 100
Mouse.LeftButton = Wiimote.Nunchuk.CButton and var.on // C = left mouse click
Mouse.RightButton = Wiimote.Nunchuk.ZButton and var.on // Z = right mouse click
if (Wiimote.Nunchuk.JoyX > var.joyfix or Wiimote.Nunchuk.JoyX < -var.joyfix) and var.on then mouse.x = mouse.x + Wiimote.Nunchuk.JoyX/50 // {Analog is used
if (Wiimote.Nunchuk.JoyY > var.joyfix or Wiimote.Nunchuk.JoyY < -var.joyfix) and var.on then mouse.y = mouse.y + Wiimote.Nunchuk.JoyY/50 // for mouse movement}

// Keys for Classic Controller
LeftControl+A = Wiimote.Classic.Up and var.on // UP = change audio
LeftControl+B = Wiimote.Classic.Down and var.on // DOWN = change subtitles
LeftShift+LeftBracket = Wiimote.Classic.Left and var.on // LEFT = previous chapter
LeftShift+RightBracket = Wiimote.Classic.Right and var.on // RIGHT = next chapter
p = Wiimote.Classic.a and var.on // a = play/pause
Space = Wiimote.Classic.b and var.on // b = info bar
LeftAlt+Enter = Wiimote.Classic.x and var.on // x = full screen on/off
W = Wiimote.Classic.ZR and var.on // ZR = rewind
F = Wiimote.Classic.R and var.on // R = fast forward
LeftShift+End = Wiimote.Classic.Minus and var.on // - = decrease volume
LeftShift+Home = Wiimote.Classic.Plus and var.on // + = increase volume
LeftControl+M = Wiimote.Classic.y and var.on // y = mute

Mouse.RightButton = Wiimote.Classic.ZL and var.on // ZL = right mouse click
Mouse.LeftButton = Wiimote.Classic.L and var.on // L = left mouse click
if (Wiimote.Classic.Joy1X > var.joyfix or Wiimote.Classic.Joy1X < -var.joyfix) and var.on then mouse.x = mouse.x + Wiimote.Classic.Joy1X/50 // {Left analog is used
if (Wiimote.Classic.Joy1Y > var.joyfix or Wiimote.Classic.Joy1Y < -var.joyfix) and var.on then mouse.y = mouse.y + Wiimote.Classic.Joy1Y/50 // for mouse movement}

// Battery info
if Wiimote.Battery <= 12 and var.warned == FALSE then
Say "Low Battery"
var.warned = TRUE
endif
var.bat = Wiimote.Battery / 192 * 100
debug ='Battery= '+var.bat+'%'

Site Admin Joined: 24 Jun 2006 Posts: 30

CDisplay WN Script by marinos35
Version 1.1

Changelog
- Now you can hide/unhide glovepie's windows also by double clicking the home button at the keyboard.
- Reconfigure of the buttons.
- When Wiimote's battery runs low (somewhere at 6%) you will hear it once from your speakers. Also the battery info now appears in percents.
- minor code changes.

COMPATIBLE with
Wiimote
Nunchuk

INCOMPATIBLE with
Sensor Bar
Classic Controller

HOW TO USE IT

ATTENTION: The GlovePIE window will hide itself once you run this script.
You can hide/unhide GlovePIE's window by double-clicking the Home button on your Wiimote or keyboard.

You can use it with only a Wiimote for basic shortcuts, or with a Nunchuk if you also want to control the mouse.

CDislpay Shortcuts
(they only work when CDisplay is the active program)

Move Page = D-Pad (Wiimote)
Previous Page = B + D-Pad Left (Wiimote)
Next Page = B + D-Pad Right (Wiimote)
Load Previous Files = - (Wiimote)
Load Next Files = + (Wiimote)
Automatic Slideshow = A (Wiimote)
First Page = 1 (Wiimote)
Last Page = 2 (Wiimote)
Go To Page - Thumbnails = Home (Wiimote)
Go To Page - Slider = B and Home (Wiimote)

Mouse Control

Move mouse = Analog (Nunchuk)
Left Click = c (Nunchuk)
Right Click = Z (Nunchuk)

WHAT THE LEDS MEAN

No LEDS = Wiimote not connected, or script not active
2+3 LEDS = Wiimote buttons (and Nunchuk if connected) are working

Save As cdisplayWN.PIE

Code:

// CDisplay Script by marinos35
// filename: cdisplayWN.PIE
// Version 1.1
// http://WiiMoveU.GooglePages.com

/*
COMPATIBLE with
Wiimote
Nunchuk

INCOMPATIBLE with
Sensor Bar
Classic Controller

HOW TO USE IT

ATTENTION: The GlovePIE window will hide itself once you run this script.
You can hide/unhide GlovePIE's window by double-clicking the Home button on your Wiimote or keyboard.

You can use it with only a Wiimote for basic shortcuts, or with a Nunchuk if you also want to control the mouse.

CDislpay Shortcuts
(they only work when CDisplay is the active program)

Move Page = D-Pad (Wiimote)
Previous Page = B + D-Pad Left (Wiimote)
Next Page = B + D-Pad Right (Wiimote)
Load Previous Files = - (Wiimote)
Load Next Files = + (Wiimote)
Automatic Slideshow = A (Wiimote)
First Page = 1 (Wiimote)
Last Page = 2 (Wiimote)
Go To Page - Thumbnails = Home (Wiimote)
Go To Page - Slider = B and Home (Wiimote)

Mouse Control

Move mouse = Analog (Nunchuk)
Left Click = c (Nunchuk)
Right Click = Z (Nunchuk)

WHAT THE LEDS MEAN

No LEDS = Wiimote not connected, or script not active
2+3 LEDS = Wiimote buttons (and Nunchuk if connected) are working
*/

// Hide/Show GlovePIE window by double-clicking the Home button
if var.run == FALSE then
var.run = TRUE
HidePie
var.hidden = TRUE
endif

if (DoubleClicked(Wiimote.Home) or (DoubleClicked(Home) and Wiimote.One == FALSE)) and var.hidden then
ShowPie
var.hidden = FALSE
elseif (DoubleClicked(Wiimote.Home) or (DoubleClicked(Home) and Wiimote.One == FALSE)) and var.hidden == FALSE then
HidePie
var.hidden = TRUE
endif

// LEDS
Wiimote.Leds = 6 // 2+3 Leds are on when everything works

// Keys for Wiimote
Up = Wiimote.Up // {D-Pad
Down = Wiimote.Down // controls
Left = Wiimote.Left and Wiimote.B == FALSE // and moves
Right = Wiimote.Right and Wiimote.B == FALSE // the page}
PageUp = Wiimote.Left and Wiimote.B // B + Left = Previous Page
PageDown = Wiimote.Right and Wiimote.B // B + Right = Next Page
LeftShift+K = Wiimote.Minus // - = Load Previous Files
LeftShift+L = Wiimote.Plus // + = Load Next Files
A = Wiimote.A // A = Automatic Slideshow
Home = Wiimote.One // 1 = First Page
End = Wiimote.Two // 2 = Last Page
P = SingleClicked(Wiimote.Home) and Wiimote.B == FALSE // Home = Thumbnails
LeftShift+P = SingleClicked(Wiimote.Home) and Wiimote.B // B + Home = Slider

// Keys for Nunchuk
var.joyfix = 5 / 100
Mouse.LeftButton = Wiimote.Nunchuk.CButton // C = left mouse click
Mouse.RightButton = Wiimote.Nunchuk.ZButton // Z = right mouse click
if (Wiimote.Nunchuk.JoyX > var.joyfix or Wiimote.Nunchuk.JoyX < -var.joyfix) then mouse.x = mouse.x + Wiimote.Nunchuk.JoyX/50 // {Analog is used
if (Wiimote.Nunchuk.JoyY > var.joyfix or Wiimote.Nunchuk.JoyY < -var.joyfix) then mouse.y = mouse.y + Wiimote.Nunchuk.JoyY/50 // for mouse movement}

// Battery info
if Wiimote.Battery <= 12 and var.warned == FALSE then
Say "Low Battery"
var.warned = TRUE
endif
var.bat = Wiimote.Battery / 192 * 100
debug ='Battery= '+var.bat+'%'

Joined: 25 May 2007 Posts: 1

so why does this script need to be posted on the main wiili page and not in the forums?

Site Admin Joined: 24 Jun 2006 Posts: 30

Because it's not one script. It is a project of scripts. I'm using for now the forum interface, but once there are more scripts I'll move them to the main page. Also I had a code error, that probably appears only in some countries, and I fix it. I wanted to be sure that the people that got the first version would know that there is an update.

syphadias wrote:

so why does this script need to be posted on the main wiili page and not in the forums?